NB.    J Brochure
NB.    Keith Smillie
NB.    Department of Computing Science
NB.    University of Alberta
NB.    Edmonton, Alberta T6G 2H1
NB.    May 2000

load 'plot'

NB. Descriptive Statistics I
Marks=: 85 79 63 91 85 69 64 78 93 48 76 81 79
size=: # 
mean=: +/ % #
min=: <./
max=: >./
summary=: size,min,mean,max
sort=: /:~
stem=: 10&* @ <. @ %&10
leaf=:10&|
diagram=: ~.@stem ;"0 stem </. leaf

NB. Descriptive Statistics II
io=: [:<:[:+/[</]            NB. "J Companion for
midpts=: [:-:2:+/\]          NB.   Statistical
fr=: +/"1 @ (=/)             NB.   Calculations"
cfr=: i.@(<:@$@[) fr io       
cfrtab=: midpts@[,.cfr       

NB. Linear Regression
x=: 12 18 24 30 36 42 48
y=: 5.3 5.7 6.3 7.2 8 8.7 8.4
'b0 b1'=: b=. y%.X=: 1,"0 x
yest=: b0+b1*x

NB. Coin Tossing
Toss=: 3 : 0
N=: y.
TossNum=: >: i. N
Heads=: +/\?N$2
Ratio=: Heads % TossNum
empty Diff=: |TossNum - 2*Heads
)

NB. Windows form for Descriptive Statistics II
WDtable=: 3 : 0               
:          
;(<"1 (x. ": y.)), each LF
)

FRTAB=: 0 : 0
pc frtab;
xywh 10 10 75 20;cc data editm ws_hscroll;
xywh 50 35 60 10;cc cname static;cn "Data";
xywh 9 45 75 65;cc frame1 groupbox;cn "Input";
xywh 15 55 30 10;cc first edit;
xywh 50 55 30 10;cc cname static;cn "First";
xywh 15 72 30 10;cc width edit;
xywh 50 72 30 10;cc cname static;cn "Width";
xywh 15 90 30 10;cc number edit;
xywh 50 90 30 10;cc cname static;cn "Number";
xywh 9 115 75 81;cc frame2 groupbox;cn "Summary";
xywh 15 125 30 10;cc samplesize edit;
xywh 50 125 30 10;cc cname static;cn "Size";
xywh 15 142 30 10;cc minimum edit;
xywh 50 142 30 10;cc cname static;cn "Minimum";
xywh 15 159 30 10;cc avg edit;
xywh 50 159 30 10;cc cname static;cn "Mean";
xywh 15 176 30 10;cc maximum edit;
xywh 50 176 30 10;cc cname static;cn "Maximum";
xywh 100 10 34 34;cc jicon button bs_ownerdraw;cn "system\examples\data\jr.ico";
xywh 100 50 34 12;cc ok button;cn "OK";
xywh 100 68 34 12;cc reset button;cn "Reset";
xywh 100 86 34 12;cc cancel button;cn "Cancel";
xywh 100 105 50 75;cc frtable editm ws_border ws_vscroll;
pas 6 6;pcenter;
rem form end;
)

Reset=: 3 : 0
wd 'set data *', '     '
wd 'set first *', '   0  '
wd 'set width *', '   0  '
wd 'set number *', '   0  '
wd 'set samplesize *', '     '
wd 'set minimum *', '     '
wd 'set avg *', '     '
wd 'set maximum *', '     '
wd 'set frtable *', '     '
)

frtab_run=: 3 : 0
wd FRTAB
wd 'setfont data "MS Sans Serif" 11 bold;'
wd 'setfont first "MS Sans Serif" 11 bold;'
wd 'setfont width "MS Sans Serif" 11 bold;'
wd 'setfont number "MS Sans Serif" 11 bold;'
wd 'setfont samplesize "MS Sans Serif" 11 bold;'
wd 'setfont minimum "MS Sans Serif" 11 bold;'
wd 'setfont avg "MS Sans Serif" 11 bold;'
wd 'setfont maximum "MS Sans Serif" 11 bold;'
wd 'setfont frtable "MS Sans Serif" 11 bold;'
wd 'pshow;'
)

frtab_ok_button=: 3 : 0
data1=: ". data
('f w n')=: ". first,' ',width,' ',number
('s0 s1 s2 s3')=: summary data1
wd 'set samplesize *',7.0&":s0
wd 'set minimum *',7.0&":s1
wd 'set avg *',7.2&":s2
wd 'set maximum *',7.0&":s3
table=: ((f--:w) + w*i.>:n) cfrtab data1
wd 'set frtable *',6.0 WDtable table
)

frtab_reset_button=: 3 : 0
Reset ''
)

frtab_close=: 3 : 0
wd'pclose'
)

frtab_cancel_button=: 3 : 0
frtab_close''
)